ハードなソフトの話

アクセスカウンタ

zoom RSS WMIを使って自力でMicrosoft Security Essentials を探してみたけど…

<<   作成日時 : 2009/10/07 23:53   >>

ブログ気持玉 0 / トラックバック 0 / コメント 0

前回のレポートは、たぶん、WMIを使ってレポートしているだけだろうという前提で、自力で調べてみることにした。
次のスクリプトをコマンドラインで実行すると、インストールされているスパイウェア対策ソフトとウイルス対策ソフトの一覧が表示される。( ファイル名: ShowAntiSpy.vbs)
Option Explicit
Dim ResultSet,Asp,Locator,Service
Set Locator = CreateObject("WbemScripting.SWbemLocator")
Set Service = Locator.ConnectServer(, "Root\SecurityCenter")

Set ResultSet  = Service.ExecQuery("Select * From AntiSpywareProduct")
Wsh.echo "インストール済みスパイウェア対策ソフト情報:" & vbCrLf
showInfo ResultSet

Set ResultSet  = Service.ExecQuery("Select * From AntiVirusProduct")
Wsh.echo "インストール済みウイルス対策ソフト情報:" & vbCrLf
showInfo ResultSet

sub showInfo(ResultSet)
    dim obj
    For Each obj In ResultSet
        with obj
            dim ind: ind = space(2)
            wsh.echo ind & "製造元           : " & .CompanyName
            wsh.echo ind & "名前             : " & .DisplayName
            if len(.pathToSignedProductExe) > 0 then
                wsh.echo ind & "署名済みEXEパス  : " & .pathToSignedProductExe
            end if
            wsh.echo ind & "バージョン       : " & .versionNumber
            ' wsh.echo ind & "有効化状態       : " & .productEnabled
            wsh.echo ind & "更新状態         : " & .productUptoDate
            wsh.echo
        End with
    Next
end sub

コマンドラインで次のように実行する:
cscript //nologo ShowAntiSpy.vbs

Windows Live OneCareがインストールされている環境では次のような結果になった。
インストール済みスパイウェア対策ソフト情報:

  製造元           : Microsoft Corporation
  名前             : Windows Defender
  バージョン       : 1.1.1505.0
  更新状態         : True

  製造元           : Microsoft Corporation
  名前             : Windows Live OneCare
  署名済みEXEパス  : C:\Program Files\Microsoft Windows OneCare Live\WinSSUI.exe
  バージョン       : 1.0.0
  更新状態         : True

インストール済みウイルス対策ソフト情報:

  製造元           : Microsoft Corporation
  名前             : Windows Live OneCare
  署名済みEXEパス  : C:\Program Files\Microsoft Windows OneCare Live\WinSSUI.exe
  バージョン       : 1.0.0
  更新状態         : True


続いてMicrosoft Security Essentials のインストールされている環境で実行すると次のような結果になった。
インストール済みスパイウェア対策ソフト情報:

  製造元           : Microsoft Corporation
  名前             : Windows Defender
  バージョン       : 1.1.1505.0
  更新状態         : True

インストール済みウイルス対策ソフト情報:



やっぱり、見つからないか…。

それにしても、Windows Live OneCareの最新版は 2.5.2900.28 のはずなんですが、

なんで 1.0.0と表示されるんだろう?

大丈夫か Microsoft!

この機能、わりと使えんのじゃないか?

テーマ

関連テーマ 一覧


月別リンク

ブログ気持玉

クリックして気持ちを伝えよう!
ログインしてクリックすれば、自分のブログへのリンクが付きます。
→ログインへ

トラックバック(0件)

タイトル (本文) ブログ名/日時

トラックバック用URL help


自分のブログにトラックバック記事作成(会員用) help

タイトル
本 文

コメント(0件)

内 容 ニックネーム/日時

コメントする help

ニックネーム
本 文
WMIを使って自力でMicrosoft Security Essentials を探してみたけど… ハードなソフトの話/BIGLOBEウェブリブログ
文字サイズ:       閉じる